home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / The World of Computer Software.iso / cmsrc392.zip / PUNCT.MF < prev    next >
Text File  |  1992-03-30  |  12KB  |  285 lines
  1. % This file contains punctuation marks common to roman and italic styles.
  2.  
  3. % Codes \0041, \0043, \0045, \0047--\0054,\ %
  4. %% \0056, \0057, \0072, \0073, \0075, \0100,\par
  5. % \0133, \0135, and \0140 are generated, as well as code |spanish_shriek|
  6. % (for a Spanish exclamation point) if that code value is known.
  7.  
  8. cmchar "Exclamation point";
  9. beginchar("!",5u#+width_adj#,asc_height#,0);
  10. italcorr asc_height#*slant-2u#-.5width_adj#+.5dot_size#;
  11. adjust_fit(0,0);
  12. pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
  13. lft x3l=hround(.5w-.5dot_size); bot y4l=0; z3=z4; dot(3,4);  % dot
  14. numeric bot_width;
  15. bot_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  16. pickup fine.nib; pos1(dot_size,0); pos2(bot_width,0);
  17. x1=x2=x3; bot y2=.25[top y4r,x_height]+1;
  18. if square_dots: top y1=h;
  19.  filldraw stroke z1e--z2e;  % stem
  20. else: top z0=(x1,h+o); y1+.5dot_size=h+o;
  21.  filldraw z1r...z0...z1l---z2l--z2r---cycle; fi  % stem and bulb
  22. penlabels(0,1,2,3,4); endchar;
  23.  
  24. iff known spanish_shriek: cmchar "Spanish open exclamation point";
  25. beginchar(spanish_shriek,5u#+width_adj#,asc_height#-desc_depth#,desc_depth#);
  26. italcorr h#*slant-2u#-.5width_adj#+.5dot_size#;
  27. adjust_fit(0,0);
  28. pickup tiny.nib; pos3(dot_size,0); pos4(dot_size,90);
  29. lft x3l=hround(.5w-.5dot_size); top y4r=h; z3=z4; dot(3,4);  % dot
  30. numeric top_width;
  31. top_width=if hefty:max(hround .8dot_size,fine.breadth) else: hair fi;
  32. pickup fine.nib; pos1(dot_size,0); pos2(top_width,0);
  33. x1=x2=x3; top y2=.25[bot y4l,h-x_height]-1;
  34. if square_dots: bot y1=-d;
  35.  filldraw stroke z1e--z2e;  % stem
  36. else: bot z0=(x1,-d-o); y1-.5dot_size=-d-o;
  37.  filldraw z1l...z0...z1r---z2r--z2l---cycle; fi  % stem and bulb
  38. penlabels(0,1,2,3,4); endchar;
  39.  
  40. cmchar "Hash mark (number sign)";
  41. if monospace: compute_spread(.6x_height#,.7x_height#);
  42. else: compute_spread(.45x_height#,.55x_height#); fi
  43. beginchar("#",15u#,asc_height#,asc_depth#);
  44. italcorr (math_axis#+.5(spread#+rule_thickness#))*slant-.5u#;
  45. adjust_fit(0,0);
  46. pickup rule.nib; lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
  47. y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
  48. draw z1--z2;  % upper bar
  49. draw z3--z4;  % lower bar
  50. lft x6=hround 3u; rt x7=hround(w-3u); x5-x6=x7-x8;
  51. x8=good.x if monospace: .6 else: .5 fi\\w;
  52. top y5=top y7=h+eps; bot y6=bot y8=-d-eps;
  53. y15=y1; z15=whatever[z5,z6]; y36=y3; z36=whatever[z5,z6];
  54. y27=y2; z27=whatever[z7,z8]; y48=y4; z48=whatever[z7,z8];
  55. draw z5--if x5>x6+1:(good.x(x15+.5),y1)--(good.x(x15-.5),y1)
  56.  --(good.x(x36+.5),y3)--(good.x(x36-.5),y3)--fi\\z6;  % left diagonal
  57. draw z7--if x7>x8+1:(good.x(x27+.5),y2)--(good.x(x27-.5),y2)
  58.  --(good.x(x48+.5),y4)--(good.x(x48-.5),y4)--fi\\z8;  % right diagonal
  59. labels(1,2,3,4,5,6,7,8,15,27,36,48); endchar;
  60.  
  61. cmchar "Per cent sign";
  62. beginchar("%",9u#+max(6u#,2fudge*(hair#+stem#)),
  63.   body_height#,body_height#-asc_height#);
  64. italcorr if hefty: .4asc_height#*slant-.5u# else: h#*slant-u# fi;
  65. adjust_fit(0,0); pickup fine.nib;
  66. numeric left_curve,right_curve;
  67. left_curve=hround 5/6[fudged.hair,fudged.stem];
  68. right_curve=max(fine.breadth,hround(fudged.hair if hefty:-2stem_corr fi));
  69. pos1(vair,90); pos2(left_curve,180); pos3(vair,270); pos4(right_curve,360);
  70. top y1r=h; lft x2r=hround u; rt x4r=hround(.5w-1.5u);
  71. bot y3r=floor(if monospace: .7 else: .5 fi\\ asc_height);
  72. x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
  73. filldraw stroke pulled_super_arc.e(1,2)(superpull)
  74.  & pulled_super_arc.e(2,3)(superpull);  % left half of upper bowl
  75. filldraw stroke super_arc.e(3,4) & super_arc.e(4,1); % right half of upper bowl
  76. pos5(vair,90); pos6(left_curve,180); pos7(vair,270); pos8(right_curve,360);
  77. bot y7r=-d; rt x8r=hround(w-u); lft x6r=hround(.5w+1.5u);
  78. top y5r=vround(if monospace: .3 else: .5 fi\\ asc_height);
  79. x5=x7=.5[x6,x8]; y6=y8=.5[y5,y7];
  80. filldraw stroke pulled_super_arc.e(5,6)(superpull)
  81.  & pulled_super_arc.e(6,7)(superpull);  % left half of lower bowl
  82. filldraw stroke super_arc.e(7,8) & super_arc.e(8,5); % right half of lower bowl
  83. pickup rule.nib; top y9=h; bot y10=-d;
  84. if hefty: x9=good.x(x5-eps); x10=good.x(x1+eps);
  85.  draw z9--z10;  % diagonal
  86. else: rt x9=hround(w-2.5u); lft x10=hround 2.5u; draw z9--z10;  % diagonal
  87.  pickup fine.nib; pos9(rule_thickness,angle(z9-z10)+90);
  88.  pos11(vair,angle(z1r-z4r)-90); pos12(vair,angle(z9-z10)+90);
  89.  path p; p=super_arc.r(1,4); z11r=point 2/3 of p; z12r=z9r;
  90.  filldraw stroke z11e{direction 2/3 of p}...{z9-z10}z12e; fi  % link
  91. penlabels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  92.  
  93. cmchar "Apostrophe";
  94. beginchar("'",5u#,asc_height#,0);
  95. italcorr asc_height#*slant+.5dot_size#-2u#;
  96. adjust_fit(0,0);
  97. x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h;
  98. if monospace: comma(1,a,dot_size,.28u,vround 1.5comma_depth);  % large comma
  99. else: comma(1,a,dot_size,.25u,comma_depth); fi  % comma with increased jut
  100. penlabels(1); endchar;
  101.  
  102. cmchar "Left parenthesis";
  103. beginchar("(",7u# if monospace: -u# fi,body_height#,paren_depth#);
  104. italcorr body_height#*slant-.5u#;
  105. adjust_fit(0,0); pickup fine.nib;
  106. pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
  107. rt x1r=rt x3r=hround(w-u); lft x2l=hround(x1-4u if monospace: +4/3u fi);
  108. top y1=h; y2=.5[y1,y3]=math_axis;
  109. filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
  110.  ...{3(x3e-x2e),y3-y2}z3e;  % arc
  111. penlabels(1,2,3); endchar;
  112.  
  113. cmchar "Right parenthesis";
  114. beginchar(")",7u# if monospace: -u# fi,body_height#,paren_depth#);
  115. italcorr math_axis#*slant-.5u#;
  116. adjust_fit(0,0); pickup fine.nib;
  117. pos1(vair,0); pos2(.75[hair,stem],0); pos3(vair,0);
  118. lft x1l=lft x3l=hround u; rt x2r=hround(x1+4u if monospace: -4/3u fi);
  119. top y1=h; y2=.5[y1,y3]=math_axis;
  120. filldraw stroke z1e{3(x2e-x1e),y2-y1}...z2e
  121.  ...{3(x3e-x2e),y3-y2}z3e;  % arc
  122. penlabels(1,2,3); endchar;
  123.  
  124. cmchar "Asterisk";
  125. beginchar("*",9u#,
  126.   if low_asterisk:math_axis#+.5x_height# else: body_height# fi,0);
  127. italcorr h#*slant-.75u#;
  128. adjust_fit(0,0);
  129. numeric ast_flare; ast_flare=hround .7[thin_join,stem];
  130. x0=.5w; y0=h-.5x_height;
  131. for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
  132.  numeric theta; theta=angle(z[d]-z0);
  133.  fill z0+.5(0,-thin_join)rotated theta
  134.   ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
  135.   ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
  136.   ---z0+.5(0,thin_join)rotated theta--cycle; endfor  % diagonal at angle |d|
  137. labels(0,[-150],[-90],[-30],30,90,150); endchar;
  138.  
  139. cmchar "Plus sign";
  140. beginarithchar("+"); pickup rule.nib;
  141. x1=x2=good.x .5w; top y1=h+eps; .5[y1,y2]=math_axis;
  142. lft x3=hround u-eps; x4=w-x3; y3=y4=math_axis;
  143. draw z1--z2;  % stem
  144. draw z3--z4;  % crossbar
  145. labels(1,2,3,4); endchar;
  146.  
  147. cmchar "Comma";
  148. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  149. define_whole_blacker_pixels(dot_diam);
  150. beginchar(",",5u#,dot_diam#,comma_depth#);
  151. adjust_fit(0,0);
  152. x1-.5dot_diam=hround(.5w-.5dot_diam); y1-.5dot_diam=0;
  153. comma(1,a,dot_diam,.2u,comma_depth);  % dot and tail
  154. penlabels(1); endchar;
  155.  
  156. cmchar "Period";
  157. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  158. define_whole_blacker_pixels(dot_diam);
  159. beginchar(".",5u#,dot_diam#,0);
  160. adjust_fit(0,0); pickup fine.nib;
  161. pos1(dot_diam,0); pos2(dot_diam,90);
  162. lft x1l=hround(.5w-.5dot_diam); bot y2l=0; z1=z2; dot(1,2);  % dot
  163. penlabels(1,2); endchar;
  164.  
  165. cmchar "Virgule (slash)";
  166. beginchar("/",9u#,body_height#,paren_depth#);
  167. italcorr body_height#*slant-.5u#;
  168. adjust_fit(0,0); pickup rule.nib;
  169. rt x1=hround(w-u)+eps; top y1=h+eps;
  170. lft x2=hround u-eps; bot y2=-d-eps;
  171. draw z1--z2;  % diagonal
  172. penlabels(1,2); endchar;
  173.  
  174. cmchar "Colon";
  175. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  176. define_whole_blacker_pixels(dot_diam);
  177. beginchar(":",5u#,x_height#,0);
  178. italcorr x_height#*slant+.5dot_diam#-2u#;
  179. adjust_fit(0,0); pickup fine.nib;
  180. pos1(dot_diam,0); pos2(dot_diam,90);
  181. lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2);  % upper dot
  182. pos3(dot_diam,0); pos4(dot_diam,90);
  183. x3=x1; bot y4l=0; z3=z4; dot(3,4);  % lower dot
  184. penlabels(1,2,3,4); endchar;
  185.  
  186. cmchar "Semicolon";
  187. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  188. define_whole_blacker_pixels(dot_diam);
  189. beginchar(";",5u#,x_height#,comma_depth#);
  190. italcorr x_height#*slant+.5dot_diam#-2u#;
  191. adjust_fit(0,0); pickup fine.nib;
  192. pos1(dot_diam,0); pos2(dot_diam,90);
  193. lft x1l=hround(.5w-.5dot_diam); top y2r=h; z1=z2; dot(1,2);  % upper dot
  194. x3-.5dot_diam=hround(.5w-.5dot_diam); y3-.5dot_diam=0;
  195. comma(3,a,dot_diam,.05u,comma_depth);  % lower dot and tail
  196. penlabels(1,2,3); endchar;
  197.  
  198. cmchar "Equals sign";
  199. compute_spread(.45x_height#,.55x_height#);
  200. beginchar("=",14u#,v_center(spread#+rule_thickness#));
  201. italcorr h#*slant-.5u#;
  202. adjust_fit(0,0); pickup rule.nib;
  203. lft x1=hround u-eps; x3=x1; x2=x4=w-x1;
  204. y1=y2; y3=y4; y1-y3=spread; .5[y1,y3]=math_axis;
  205. draw z1--z2;  % upper bar
  206. draw z3--z4;  % lower bar
  207. labels(1,2,3,4); endchar;
  208.  
  209. cmchar "At sign";
  210. beginchar("@",14u#,asc_height#,0);
  211. italcorr .7asc_height#*slant-.5u#;
  212. adjust_fit(0,if hefty or monospace:-2u# else: 0 fi);
  213. pickup fine.nib; pos0(fudged.hair,0); pos1(vair,90);
  214. pos2(fudged.stem,180); pos3(vair,270);
  215. pos4(fudged.stem,-180); pos5(fudged.stem,-180);
  216. pos6(vair,-90); pos7(fudged.hair,0);
  217. pos8(vair,90); pos9(fudged.hair,180);
  218. pos10(vair,270); pos11(.5[vair,flare],360);
  219. x1=x3=.5[x0,x2]; y0=y2=.5[y1,y3];
  220. x8=x10=.5w; y7=y9=.5[y8,y10];
  221. lft x9r=hround u; x7=w-x9; top y8r=h+oo; bot y10r=-oo;
  222. top y1r=vround(.8[y10,y8]+.5vair); bot y3r=vround(.2[y10,y8]-.5vair);
  223. x6l=1/3[x5l,x7l]; y6=y3; y11=good.y(.1[y10,y8]-.5);
  224. x0=x4=x5; y4=.8[y3,y1]; y5=2/3[y7,y6];
  225. if hefty or monospace: lft x2r=hround(5u-.5fudged.stem);
  226.  rt x0r=hround(w-3u); x11r=x0r;
  227. else: lft x2r=hround 3.4u; x0=w-x2; x11r=x7r; fi
  228. filldraw stroke super_arc.e(1,2) & super_arc.e(2,3);  % left inner bowl
  229. filldraw stroke super_arc.e(3,0) & super_arc.e(0,1);  % right inner bowl
  230. filldraw stroke super_arc.e(8,9) & super_arc.e(9,10)
  231.  & term.e(10,11,right,1,4);  % left outer bowl and terminal
  232. if hefty or monospace: {{interim superness:=hein_super;
  233.   filldraw stroke super_arc.e(0,8)}};  % link
  234. else: (x,y6r)=whatever[z6l,z7l]; x6r:=x;
  235.  filldraw stroke z4e---z5e...z6e{right}...{up}z7e
  236.   & super_arc.e(7,8); fi % stem and link
  237. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  238.  
  239. cmchar "Left bracket";
  240. numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
  241. beginchar("[",wd#,body_height#,paren_depth#);
  242. italcorr body_height#*slant;
  243. adjust_fit(0,0);
  244. numeric top_thickness,side_thickness;
  245. if hefty: top_thickness=vair;
  246.  side_thickness=max(crisp.breadth,stem-2stem_corr);
  247. else: top_thickness=side_thickness=rule_thickness; fi;
  248. pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
  249. top y1=h; bot y2=-d; lft x1l=lft x2l=hround(2.5u-.5side_thickness)-1-eps;
  250. filldraw stroke z1e--z2e;  % stem
  251. pos3(top_thickness,90); pos4(top_thickness,90);
  252. pos5(top_thickness,90); pos6(top_thickness,90);
  253. x3=x5=x1l; rt x4=rt x6=ceiling(w-.4u)+eps; y3r=y4r=y1; y5l=y6l=y2;
  254. filldraw stroke z3e--z4e;  % upper bar
  255. filldraw stroke z5e--z6e;  % lower bar
  256. penlabels(1,2,3,4,5,6); endchar;
  257.  
  258. cmchar "Right bracket";
  259. numeric wd#; wd#=max(5u#,4.5u#+.5if hefty:stem# else:rule_thickness# fi);
  260. beginchar("]",wd#,body_height#,paren_depth#);
  261. italcorr body_height#*slant-2u#+.5if hefty:stem# else:rule_thickness# fi;
  262. adjust_fit(0,0);
  263. numeric top_thickness,side_thickness;
  264. if hefty: top_thickness=vair;
  265.  side_thickness=max(crisp.breadth,stem-2stem_corr);
  266. else: top_thickness=side_thickness=rule_thickness; fi;
  267. pickup crisp.nib; pos1(side_thickness,0); pos2(side_thickness,0);
  268. top y1=h; bot y2=-d; rt x1r=rt x2r=hround(w-2.5u+.5side_thickness)+1+eps;
  269. filldraw stroke z1e--z2e;  % stem
  270. pos3(top_thickness,90); pos4(top_thickness,90);
  271. pos5(top_thickness,90); pos6(top_thickness,90);
  272. x3=x5=x1r; lft x4=lft x6=floor .4u-eps; y3r=y4r=y1; y5l=y6l=y2;
  273. filldraw stroke z3e--z4e;  % upper bar
  274. filldraw stroke z5e--z6e;  % lower bar
  275. penlabels(1,2,3,4,5,6); endchar;
  276.  
  277. cmchar "Reverse apostrophe";
  278. beginchar("`",5u#,asc_height#,0);
  279. italcorr asc_height#*slant+.5dot_size#-2u#;
  280. adjust_fit(0,0);
  281. x1-.5dot_size=hround(.5w-.5dot_size); y1+.5dot_size=h-comma_depth;
  282. if monospace: ammoc(1,a,dot_size,.28u,vround 1.5comma_depth);  % large ammoc
  283. else: ammoc(1,a,dot_size,.25u,comma_depth); fi  % normal ammoc
  284. penlabels(1); endchar;
  285.